Greg Kroah-Hartman
598cf27219
Link: https://lore.kernel.org/r/20260217200002.683975158@linuxfoundation.org Tested-by: Florian Fainelli <florian.fainelli@broadcom.com> Tested-by: Takeshi Ogasawara <takeshi.ogasawara@futuring-girl.com> Tested-by: Peter Schneider <pschneider1968@googlemail.com> Tested-by: Jon Hunter <jonathanh@nvidia.com> Tested-by: Salvatore Bonaccorso <carnil@debian.org> Tested-by: Brett A C Sheffield <bacs@librecast.net> Tested-by: Mark Brown <broonie@kernel.org> Tested-by: Luna Jernberg <droidbittin@gmail.com> Tested-by: Ronald Warsow <rwarsow@gmx.de> Tested-by: Justin M. Forbes <jforbes@fedoraproject.org> Tested-by: Ron Economos <re@w6rz.net> Tested-by: Miguel Ojeda <ojeda@kernel.org> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
75 lines
1.5 KiB
ArmAsm
75 lines
1.5 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
/*
|
|
* Copyright (c) 2023 Ventana Micro Systems Inc.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <linux/export.h>
|
|
#include <asm/asm.h>
|
|
#include <asm/alternative-macros.h>
|
|
#include <asm/hwcap.h>
|
|
#include <asm/insn-def.h>
|
|
#include <asm/page.h>
|
|
|
|
#define CBOZ_ALT(order, old, new) \
|
|
ALTERNATIVE(old, new, 0, \
|
|
((order) << 16) | RISCV_ISA_EXT_ZICBOZ, \
|
|
CONFIG_RISCV_ISA_ZICBOZ)
|
|
|
|
/* void clear_page(void *page) */
|
|
SYM_FUNC_START(clear_page)
|
|
li a2, PAGE_SIZE
|
|
|
|
/*
|
|
* If Zicboz isn't present, or somehow has a block
|
|
* size larger than 4K, then fallback to memset.
|
|
*/
|
|
CBOZ_ALT(12, "j .Lno_zicboz", "nop")
|
|
|
|
lw a1, riscv_cboz_block_size
|
|
add a2, a0, a2
|
|
.Lzero_loop:
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBOZ_ALT(11, "bltu a0, a2, .Lzero_loop; ret", "nop; nop")
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBOZ_ALT(10, "bltu a0, a2, .Lzero_loop; ret", "nop; nop")
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBOZ_ALT(9, "bltu a0, a2, .Lzero_loop; ret", "nop; nop")
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBOZ_ALT(8, "bltu a0, a2, .Lzero_loop; ret", "nop; nop")
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
CBO_ZERO(a0)
|
|
add a0, a0, a1
|
|
bltu a0, a2, .Lzero_loop
|
|
ret
|
|
.Lno_zicboz:
|
|
li a1, 0
|
|
tail __memset
|
|
SYM_FUNC_END(clear_page)
|
|
EXPORT_SYMBOL(clear_page)
|