Greg Kroah-Hartman
598cf27219
Link: https://lore.kernel.org/r/20260217200002.683975158@linuxfoundation.org Tested-by: Florian Fainelli <florian.fainelli@broadcom.com> Tested-by: Takeshi Ogasawara <takeshi.ogasawara@futuring-girl.com> Tested-by: Peter Schneider <pschneider1968@googlemail.com> Tested-by: Jon Hunter <jonathanh@nvidia.com> Tested-by: Salvatore Bonaccorso <carnil@debian.org> Tested-by: Brett A C Sheffield <bacs@librecast.net> Tested-by: Mark Brown <broonie@kernel.org> Tested-by: Luna Jernberg <droidbittin@gmail.com> Tested-by: Ronald Warsow <rwarsow@gmx.de> Tested-by: Justin M. Forbes <jforbes@fedoraproject.org> Tested-by: Ron Economos <re@w6rz.net> Tested-by: Miguel Ojeda <ojeda@kernel.org> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
46 lines
1.3 KiB
ArmAsm
46 lines
1.3 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
|
|
#include <linux/export.h>
|
|
#include <linux/linkage.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/nospec-insn.h>
|
|
|
|
#define R2_OFF 0
|
|
#define R5_OFF (R2_OFF + (5 - 2 + 1) * 8)
|
|
#define R14_OFF (R5_OFF + 8)
|
|
#define RETADDR_OFF (R14_OFF + 8)
|
|
#define R15_OFF (RETADDR_OFF + 8)
|
|
#define BACKCHAIN_OFF (R15_OFF + 8)
|
|
#define FRAME_SIZE (BACKCHAIN_OFF + 8)
|
|
#define FRAME_OFF (STACK_FRAME_OVERHEAD - FRAME_SIZE)
|
|
#if (FRAME_OFF + BACKCHAIN_OFF) != __SF_BACKCHAIN
|
|
#error Stack frame layout calculation is broken
|
|
#endif
|
|
|
|
GEN_BR_THUNK %r1
|
|
|
|
SYM_FUNC_START(arch_bpf_timed_may_goto)
|
|
/*
|
|
* This function has a special ABI: the parameters are in %r12 and
|
|
* %r13; the return value is in %r12; all GPRs except %r0, %r1, and
|
|
* %r12 are callee-saved; and the return address is in %r0.
|
|
*/
|
|
stmg %r2,%r5,FRAME_OFF+R2_OFF(%r15)
|
|
stg %r14,FRAME_OFF+R14_OFF(%r15)
|
|
stg %r0,FRAME_OFF+RETADDR_OFF(%r15)
|
|
stg %r15,FRAME_OFF+R15_OFF(%r15)
|
|
lgr %r1,%r15
|
|
lay %r15,-FRAME_SIZE(%r15)
|
|
stg %r1,__SF_BACKCHAIN(%r15)
|
|
|
|
lay %r2,0(%r12,%r13)
|
|
brasl %r14,bpf_check_timed_may_goto
|
|
lgr %r12,%r2
|
|
|
|
lg %r15,FRAME_SIZE+FRAME_OFF+R15_OFF(%r15)
|
|
lmg %r2,%r5,FRAME_OFF+R2_OFF(%r15)
|
|
lg %r14,FRAME_OFF+R14_OFF(%r15)
|
|
lg %r1,FRAME_OFF+RETADDR_OFF(%r15)
|
|
BR_EX %r1
|
|
SYM_FUNC_END(arch_bpf_timed_may_goto)
|