Greg Kroah-Hartman
598cf27219
Link: https://lore.kernel.org/r/20260217200002.683975158@linuxfoundation.org Tested-by: Florian Fainelli <florian.fainelli@broadcom.com> Tested-by: Takeshi Ogasawara <takeshi.ogasawara@futuring-girl.com> Tested-by: Peter Schneider <pschneider1968@googlemail.com> Tested-by: Jon Hunter <jonathanh@nvidia.com> Tested-by: Salvatore Bonaccorso <carnil@debian.org> Tested-by: Brett A C Sheffield <bacs@librecast.net> Tested-by: Mark Brown <broonie@kernel.org> Tested-by: Luna Jernberg <droidbittin@gmail.com> Tested-by: Ronald Warsow <rwarsow@gmx.de> Tested-by: Justin M. Forbes <jforbes@fedoraproject.org> Tested-by: Ron Economos <re@w6rz.net> Tested-by: Miguel Ojeda <ojeda@kernel.org> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
78 lines
1.7 KiB
Plaintext
78 lines
1.7 KiB
Plaintext
// SPDX-License-Identifier: GPL-2.0-only
|
|
/// Correct the size argument to alloc functions
|
|
///
|
|
//# This makes an effort to find cases where the argument to sizeof is wrong
|
|
//# in memory allocation functions by checking the type of the allocated memory
|
|
//# when it is a double pointer and ensuring the sizeof argument takes a pointer
|
|
//# to the the memory being allocated. There are false positives in cases the
|
|
//# sizeof argument is not used in constructing the return value. The result
|
|
//# may need some reformatting.
|
|
//
|
|
// Confidence: Moderate
|
|
// Copyright: (C) 2014 Himangi Saraogi.
|
|
// Comments:
|
|
// Options:
|
|
|
|
virtual patch
|
|
virtual context
|
|
virtual org
|
|
virtual report
|
|
|
|
//----------------------------------------------------------
|
|
// For context mode
|
|
//----------------------------------------------------------
|
|
|
|
@depends on context disable sizeof_type_expr@
|
|
type T;
|
|
T **x;
|
|
@@
|
|
|
|
x =
|
|
<+...sizeof(
|
|
* T
|
|
)...+>
|
|
|
|
//----------------------------------------------------------
|
|
// For patch mode
|
|
//----------------------------------------------------------
|
|
|
|
@depends on patch disable sizeof_type_expr@
|
|
type T;
|
|
T **x;
|
|
@@
|
|
|
|
x =
|
|
<+...sizeof(
|
|
- T
|
|
+ *x
|
|
)...+>
|
|
|
|
//----------------------------------------------------------
|
|
// For org and report mode
|
|
//----------------------------------------------------------
|
|
|
|
@r depends on (org || report) disable sizeof_type_expr@
|
|
type T;
|
|
T **x;
|
|
position p;
|
|
@@
|
|
|
|
x =
|
|
<+...sizeof(
|
|
T@p
|
|
)...+>
|
|
|
|
@script:python depends on org@
|
|
p << r.p;
|
|
@@
|
|
|
|
coccilib.org.print_todo(p[0], "WARNING sizeof argument should be pointer type, not structure type")
|
|
|
|
@script:python depends on report@
|
|
p << r.p;
|
|
@@
|
|
|
|
msg="WARNING: Use correct pointer type argument for sizeof"
|
|
coccilib.report.print_report(p[0], msg)
|
|
|