Greg Kroah-Hartman
598cf27219
Link: https://lore.kernel.org/r/20260217200002.683975158@linuxfoundation.org Tested-by: Florian Fainelli <florian.fainelli@broadcom.com> Tested-by: Takeshi Ogasawara <takeshi.ogasawara@futuring-girl.com> Tested-by: Peter Schneider <pschneider1968@googlemail.com> Tested-by: Jon Hunter <jonathanh@nvidia.com> Tested-by: Salvatore Bonaccorso <carnil@debian.org> Tested-by: Brett A C Sheffield <bacs@librecast.net> Tested-by: Mark Brown <broonie@kernel.org> Tested-by: Luna Jernberg <droidbittin@gmail.com> Tested-by: Ronald Warsow <rwarsow@gmx.de> Tested-by: Justin M. Forbes <jforbes@fedoraproject.org> Tested-by: Ron Economos <re@w6rz.net> Tested-by: Miguel Ojeda <ojeda@kernel.org> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
65 lines
1.4 KiB
ArmAsm
65 lines
1.4 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
/*
|
|
* Copyright (c) 2015, Linaro Limited
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <linux/arm-smccc.h>
|
|
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/opcodes-sec.h>
|
|
#include <asm/opcodes-virt.h>
|
|
#include <asm/unwind.h>
|
|
|
|
/*
|
|
* Wrap c macros in asm macros to delay expansion until after the
|
|
* SMCCC asm macro is expanded.
|
|
*/
|
|
.macro SMCCC_SMC
|
|
__SMC(0)
|
|
.endm
|
|
|
|
.macro SMCCC_HVC
|
|
__HVC(0)
|
|
.endm
|
|
|
|
.macro SMCCC instr
|
|
UNWIND( .fnstart)
|
|
mov r12, sp
|
|
push {r4-r7}
|
|
UNWIND( .save {r4-r7})
|
|
ldm r12, {r4-r7}
|
|
\instr
|
|
ldr r4, [sp, #36]
|
|
cmp r4, #0
|
|
beq 1f // No quirk structure
|
|
ldr r5, [r4, #ARM_SMCCC_QUIRK_ID_OFFS]
|
|
cmp r5, #ARM_SMCCC_QUIRK_QCOM_A6
|
|
bne 1f // No quirk present
|
|
str r6, [r4, #ARM_SMCCC_QUIRK_STATE_OFFS]
|
|
1: pop {r4-r7}
|
|
ldr r12, [sp, #(4 * 4)]
|
|
stm r12, {r0-r3}
|
|
bx lr
|
|
UNWIND( .fnend)
|
|
.endm
|
|
|
|
/*
|
|
* void smccc_smc(unsigned long a0, unsigned long a1, unsigned long a2,
|
|
* unsigned long a3, unsigned long a4, unsigned long a5,
|
|
* unsigned long a6, unsigned long a7, struct arm_smccc_res *res,
|
|
* struct arm_smccc_quirk *quirk)
|
|
*/
|
|
ENTRY(__arm_smccc_smc)
|
|
SMCCC SMCCC_SMC
|
|
ENDPROC(__arm_smccc_smc)
|
|
|
|
/*
|
|
* void smccc_hvc(unsigned long a0, unsigned long a1, unsigned long a2,
|
|
* unsigned long a3, unsigned long a4, unsigned long a5,
|
|
* unsigned long a6, unsigned long a7, struct arm_smccc_res *res,
|
|
* struct arm_smccc_quirk *quirk)
|
|
*/
|
|
ENTRY(__arm_smccc_hvc)
|
|
SMCCC SMCCC_HVC
|
|
ENDPROC(__arm_smccc_hvc)
|